***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 27, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5224B A K 
.param
+vc0 = 1.046e-10	vc1 = 2.216e-8		vc2 = 1.400		vc3 = 1.183e-5		vc4 = 7.236e-0
+tc1 = 3.551e-3		tc2 = 3.021e-3		tc3 = 3.371e-3		tc4 = 1.021e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 6.620e-15	   n = 1.103		  rs = 4.586e-1
+ibv = 5e-3		 nbv = 4.2		  bv = 2.8
+ikf = 2.428e-1
***** capacitance parameter *****
+cjo = 2.203e-10	   m = 3.275e-1		  vj = 7.744e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.135		 xti = 3
+trs1 = 1.045e-3	trs2 = 5.785e-6		tikf = 5e-3
+tbv1 = -9.821e-4	tbv2 = 1.904e-6	
.ends MMSZ5224B
*$
